Membuat Game Pesawat
Mei 11, 2010 at 5:59 am Tinggalkan Komentar
Langkah 1. Persiapan
Pertama buat dokumen baru (CTRL + N, pilih Flash Document) dan mengubah tingkat bingkai ke 45 di panel properti (Frame rate 46 fbs), ini akan memastikan permainan akan berjalan baik dan lancar.
Langkah 2. Menggambar kapal
Pertama kita gambar dulu pesawatnya dengan brus tool, atau kita import dari ms. office.
Selanjutnya klik di pesawat tekan F8 kemudian di convert to symbol
ketik “pesawat” tanpa kutip, pilih movie cklip tekan tombol Ok.
Klik di pesawat yang sudah dijadikan movieclip, tekan F9 dan ketik/copykan kode berikut :
1 2 3 4 5 6 7 8 9 10 11 |
onClipEvent(enterFrame){
if(Key.isDown(Key.LEFT)){
_x -= 6;
}else if(Key.isDown(Key.RIGHT)){
_x += 6;
}else if(Key.isDown(Key.UP)){
_y -= 6;
}else if(Key.isDown(Key.DOWN)){
_y += 6;
}
}
|
Langkah 4. Pengujian dan finishing
Tekan CTRL + ENTER untuk menguji permainan Anda, tekan tombol panah kanan, kiri, atas dan bawah untuk menggerakkan pesawat.
Menggambar Peluru
Langkah 1. Menggambar peluru
Mulailah dengan menggambar peluru atau laser, mana saja yang Anda inginkan. Pastikan itu menghadap ke atas!
Selanjutnya klik pada pesawat dan tekan F8, convert to symbol ketik “peluru” tanpa kutip, pilih movieklip, tekan Ok.
Sekarang menghapus movieklip peluru yang ada di stage tadi yang baru Anda gambar. Ya, ini mungkin terdengar aneh, tapi jangan khawatir – yang movieklip sebenarnya masih ada dalam dokumen Flash Anda.
tekan CTRL + L untuk membuka Perpustakaan yang menampilkan unsur-unsur dalam dokumen Anda, peluru harus di sana!
Langkah 2. Menghubungkan peluru
Di Library, pilih peluru dan klik kanan. Dalam menu pilih “Linkage …” (atau “Properties …” jika Anda menggunakan Adobe Flash CS4 atau atas).
Pada jendela baru centang “Ekspor untuk ActionScript” yang membuka kemampuan untuk memberikan movieklip identifier. Masukkan “bullet”, sekarang tekan tombol “OK” dan tutup Library.
Langkah 3. Coding
Pilih movieklip pesawat dan tekan F9 untuk membuka panel kode, lalu ganti seluruh kode (kode dari bagian 1 harus ada) dengan:
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 |
onClipEvent(load){
timer = 0;
i = 0;
}
onClipEvent(enterFrame){
if(timer > 0){
timer--;
}
if(Key.isDown(Key.LEFT)){
_x -= 6;
}else if(Key.isDown(Key.RIGHT)){
_x += 6;
}else if(Key.isDown(Key.UP)){
_y -= 6;
}else if(Key.isDown(Key.DOWN)){
_y += 6;
}
if(Key.isDown(Key.SPACE)){
if(timer == 0){
_root.attachMovie("bullet", "bullet"+i, _root.getNextHighestDepth());
_root["bullet"+i]._x = _x;
_root["bullet"+i]._y = _y-20;
_root["bullet"+i].onEnterFrame = function(){
this._y -= 10;
if(this._y < -30){
this.removeMovieClip();
}
}
i++;
timer = 20;
}
}
}
|
Langkah 4. Pengujian dan finishing
Tekan CTRL + ENTER untuk tes permainan, Anda harus mampu menembak peluru menggunakan spasi!
Membuat Pesawat Lawan
Langkah1. Gambar atau import pesawat lawan
Langkahnya sama seperti pada saat membuat pesawat pertama!
untuk pesawat yang kedua posisi diputar sehingga depan pesawat saling berhadapan!
Jika Anda telah melakukannya, pilih pesawatmusuh dan tekan F8. Pada jendela baru ketik |”enemy” tanpa kutip pilih movieklip dan tekan OK.
Sekarang ke stage dan menghapus movieklip “enemy” yang seperti kita lakukan dengan peluru. Sekali lagi, masih di Library tidak di stage lagi, tapi tidak apa-apa – kita akan menciptakan musuh dinamis.
Hit CTRL + L (pada Windows) untuk membuka Library proyek Anda yang menampilkan unsur-unsur dalam dokumen Anda, kapal musuh harus ada!
Langkah 2. Menghubungkan musuh
Di Perpustakaan, pilih pesawat ruang angkasa musuh dan klik kanan. Dalam menu pilih “Linkage …” (atau “Properties …” jika Anda menggunakan Adobe Flash CS4 atau atas).
Di jendela baru centang “Export for ActionScript” yang membuka kemampuan untuk memberikan movieklip identifier. Masukkan “musuh”, sekarang tekan tombol “OK” dan tutup perpustakaan.
Langkah 3. Coding bagian 1
Ini mungkin akan menjadi kode paling canggih dan sulit dari keseluruhan proyek agar mengambil waktu Anda, membacanya perlahan dan mencoba untuk membayangkan apa yang setiap baris kode kata dalam bahasa Inggris biasa.
Pertama, mari kita menempatkan kode berikut pada timeline utama. Apa itu? Pada dasarnya Anda mengklik suatu tempat di panggung (bukan pada objek apapun, sehingga mengklik latar belakang baik-baik saja) dan tekan F9 untuk membuka panel kode – kemudian, menempatkan kode Anda di sana. Jika Anda kemudian membuat file Flash (CTRL + ENTER, ingatlah), Anda akan melihat tidak ada kesalahan jika Anda melakukannya dengan benar?.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 |
i = 0;
enemies = [];
spawnEnemy = function(){
_root.attachMovie("enemy", "enemy"+i, _root.getNextHighestDepth());
_root["enemy"+i]._x = random(Stage.width);
_root["enemy"+i]._y = 0;
enemies.push("enemy"+i);
_root["enemy"+i].onEnterFrame = function(){
this._y += 3;
if(this._y > Stage.height){
for(e = 0; e < _root.enemies.length; e++){
if(_root.enemies[e] == this._name){
_root.enemies.splice(e, 1);
}
}
this.removeMovieClip();
}
}
i++;
}
enemy_interval = setInterval(spawnEnemy, 2000);
|
Langkah 4. Coding bagian 2
Oke, sekarang untuk kode selanjutnya Anda harus mencari kode untuk peluru untuk dibuat yang pada movieklip pemain. Jadi silakan klik player (pesawat ruang angkasa) dan tekan F9 untuk membuka panel coding lagi.
Anda sekarang dapat melihat kode ini:
1 2 3 4 5 6 |
_root["bullet"+i].onEnterFrame = function(){
this._y -= 10;
if(this._y < -30){
this.removeMovieClip();
}
}
|
Ganti dengan:
1 2 3 4 5 6 7 8 9 10 11 12 13 14 |
_root["bullet"+i].onEnterFrame = function(){
this._y -= 10;
if(this._y < -30){
this.removeMovieClip();
}
for(k = 0; k < _root.enemies.length; k++){
if(this.hitTest(_root[_root.enemies[k]])){
this.removeMovieClip();
_root[_root.enemies[k]].removeMovieClip();
_root.enemies.splice(k, 1);
}
}
}
|
Langkah 5. Pengujian dan finishing
Sekarang tekan CTRL + ENTER untuk menguji permainan, Anda harus mampu menembak peluru dan memukul musuh.
Entry filed under: 1. Tags: .
Trackback this post | Subscribe to the comments via RSS Feed